Direction field for y'=t-y

Define the ODE right hand side function:

f[t_,y_]:=t-y;

Plot the direction field:

VectorPlot[{1,f[t,y]},{t,-2,2},{y,-2,2}]

Solve the ODE numerically:

SolveIVP[t0_,y0_]:=NDSolve[{y'[t]==f[t,y[t]],y[t0]==y0},y,{t,-2,2}];

Plot the direction field together with the numerical solution, for different initial conditions:

Show[VectorPlot[{1,f[t,y]},{t,-2,2},{y,-2,2}],
Table[Plot[Evaluate[y[t]/.SolveIVP[ty[[1]],ty[[2]]]],{t,-2,2}],{ty,{{-2,1},{-2,-1},{-1,-2},{0,-2},{1,-2}}}]]

Direction field for y'=y(y+1)

Define the ODE right hand side function:

f[t_,y_]:=y(y+1);

Plot the direction field:

VectorPlot[{1,f[t,y]},{t,0,4},{y,-2,1}]

Solve the ODE numerically:

SolveIVP[t0_,y0_]:=NDSolve[{y'[t]==f[t,y[t]],y[t0]==y0},y,{t,0,4}];

Plot the direction field together with the numerical solution, with the initial condition controllable:

Manipulate[Show[VectorPlot[{1,f[t,y]},{t,0,4},{y,-2,1}],
Plot[Evaluate[y[t]/.SolveIVP[0,y0]],{t,0,4}]],{y0,-2,0.01,0.01}]